Josefina Martinez
Department of Economics
University of Colorado
$TITLE Model M1_3S: Closed 2x2 Economy with Joint Production
$ontext
Joint production is easily accommodated in the general
equilibrium framework. Here we revise the data from model
M1_1 so that goods X and Y are each produced by sectors A and B.
Production Sectors Consumers
Markets | A B W | CONS
------------------------------------------------------
PX | 80 20 -100 |
PY | 20 80 -100 |
PW | 200 | -200
PL | -40 -60 | 100
PK | -60 -40 | 100
------------------------------------------------------
$offtext
* Declare GAMS parameters which we will use in model specification:
SCALAR TA Ad-valorem tax rate for sector A inputs /0/;
$ONTEXT
$MODEL: M1_3S
$SECTORS:
A ! Activity level for sector A (80:20 for X:Y)
B ! Activity level for sector B (20:80 for X:Y)
W ! Activity level for sector W (Hicksian welfare index)
$COMMODITIES:
PX ! Price index for commodity X
PY ! Price index for commodity Y
PL ! Price index for primary factor L
PK ! Price index for primary factor K
PW ! Price index for welfare (expenditure function)
$CONSUMERS:
CONS ! Income level for consumer CONS
* On the first line of the production declaration, the t:'tvalue'
* field specifies the transformation elasticity between outputs.
* 'tvalue' can be zero but not infinity.
$PROD:A t:2 s:1
O:PX Q:80
O:PY Q:20
I:PL Q:40.0 A:CONS T:TA
I:PK Q:60.0 A:CONS T:TA
$PROD:B t:1.5 s:1
O:PX Q:20
O:PY Q:80
I:PL Q:60
I:PK Q:40
$PROD:W s:1
O:PW Q:200
I:PX Q:100
I:PY Q:100
$DEMAND:CONS
D:PW Q:200
E:PL Q:100
E:PK Q:100
$OFFTEXT
$SYSINCLUDE mpsgeset M1_3S
* Fix a numeraire:
PL.FX = 1;
* Benchmark replication:
M1_3S.ITERLIM = 0;
$INCLUDE M1_3S.GEN
SOLVE M1_3S USING MCP;
M1_3S.ITERLIM = 2000;
* Counterfactual: 10% tax on A sector inputs:
TA = 0.10;
$INCLUDE M1_3S.GEN
SOLVE M1_3S USING MCP;
* Counterfactual: 100% tax on A sector inputs:
TA = 1.00;
$INCLUDE M1_3S.GEN
SOLVE M1_3S USING MCP;
*----------------------------------------------------------------------------
* Algebraic representation:
EQUATIONS
PRF_A Zero profit for sector X
PRF_B Zero profit for sector Y
PRF_W Zero profit for sector W (Hicksian welfare index)
MKT_X Supply-demand balance for commodity X
MKT_Y Supply-demand balance for commodity Y
MKT_L Supply-demand balance for primary factor L
MKT_K Supply-demand balance for primary factor L
MKT_W Supply-demand balance for aggregate demand
I_CONS Income definition for CONS;
* Write the profit constraints as inequalities -- the tax
* can cause sector A to shut down completely:
PRF_A.. 100 * PL**0.4 * PK**0.6 * (1+TA) =G=
100 * (0.8 * PX**(1+2.0) + 0.2 * PY**(1+2.0))**(1/(1+2.0));
PRF_B.. 100 * PL**0.6 * PK**0.4 =G=
100 * (0.2 * PX**(1+1.5) + 0.8 * PY**(1+1.5))**(1/(1+1.5));
PRF_W.. 200 * PX**0.5 * PY**0.5 =E= 200 * PW;
MKT_X.. 80 * A * (PX/(0.8*PX**(1+2.0)+0.2*PY**(1+2.0))**(1/(1+2.0)))**2
+ 20 * B * (PX/(0.2*PX**(1+1.5)+0.8*PY**(1+1.5))**(1/(1+1.5)))**1.5
=E= 100 * W * PX**0.5 * PY**0.5 / PX;
MKT_Y.. 20 * A * (PY/(0.8*PX**(1+2.0)+0.2*PY**(1+2.0))**(1/(1+2.0)))**2.0
+ 80 * B * (PY/(0.2*PX**(1+1.5)+0.8*PY**(1+1.5))**(1/(1+1.5)))**1.5
=E= 100 * W * PX**0.5 * PY**0.5 / PY;
MKT_W.. 200 * W =E= CONS / PW;
MKT_L.. 100 =E= 40 * A * PL**0.4 * PK**0.6 / PL +
60 * B * PL**0.6 * PK**0.4 / PL;
MKT_K.. 100 =E= 60 * A * PL**0.4 * PK**0.6 / PK +
40 * B * PL**0.6 * PK**0.4 / PK;
I_CONS.. CONS =E= 100*PL + 100*PK + TA*100*A*PL**0.4*PK**0.6;
MODEL ALGEBRAIC /PRF_A.A, PRF_B.B, PRF_W.W, MKT_X.PX, MKT_Y.PY, MKT_L.PL,
MKT_K.PK, MKT_W.PW, I_CONS.CONS /;
* Check the benchmark:
A.L=1; B.L=1; W.L=1; PX.L=1; PY.L=1; PK.L=1; PW.L=1; CONS.L=200;
TA = 0;
ALGEBRAIC.ITERLIM = 0;
SOLVE ALGEBRAIC USING MCP;
ALGEBRAIC.ITERLIM = 2000;
* Solve the same counterfactuals:
TA = 0.10;
SOLVE ALGEBRAIC USING MCP;
TA = 1.00;
SOLVE ALGEBRAIC USING MCP;
*--------------------------------------------------------------------------
* EXERCISE (1): Revise the model structure to represent an
* infinite elasticity of transformation in sector A. You will
* need to rewrite the model with two sectors A1 and A2. These
* will have identical cost structure, one producing good X and
* the other producing good Y.
TA = 0;
$ONTEXT
$MODEL:A1_A2
$SECTORS:
A1 ! Activity level for sector A producing X
A2 ! Activity level for sector A producing Y
B ! Activity level for sector B
W ! Activity level for sector W (Hicksian welfare index)
$COMMODITIES:
PX ! Price index for commodity A
PY ! Price index for commodity B
PL ! Price index for commodity L
PK ! Price index for commodity K
PW ! Price index for Welfare (expenditure function)
$CONSUMERS:
CONS ! Income level for consumer CONS
$PROD:A1 s:1
O:PX Q:80
I:PL Q:32 A:CONS T:TA
I:PK Q:48 A:CONS T:TA
$PROD:A2 s:1
O:PY Q:20
I:PL Q:8 A:CONS T:TA
I:PK Q:12 A:CONS T:TA
$PROD:B t:1.5 s:1
O:PY Q:80
O:PX Q:20
I:PL Q:60
I:PK Q:40
$PROD:W s:1
O:PW Q:200
I:PX Q:100
I:PY Q:100
$DEMAND:CONS
D:PW Q:200
E:PL Q:100
E:PK Q:100
$OFFTEXT
$SYSINCLUDE mpsgeset A1_A2
* Benchmark replication
A1_A2.ITERLIM = 0;
$INCLUDE A1_A2.GEN
SOLVE A1_A2 USING MCP;
A1_A2.ITERLIM = 2000;
* Counterfactual: 10% tax on A sectors (A1 and A2) inputs:
TA = 0.10;
$INCLUDE A1_A2.GEN
SOLVE A1_A2 USING MCP;
* Counterfactual: 100% tax on A sectors (A1 and A2) inputs:
TA = 1.00;
$INCLUDE A1_A2.GEN
SOLVE A1_A2 USING MCP;
The solution listing appears as follows:
S O L V E S U M M A R Y
MODEL M1_3S
LOWER LEVEL UPPER MARGINAL
---- VAR A . 1.000 +INF .
---- VAR B . 1.000 +INF .
---- VAR W . 1.000 +INF .
---- VAR PX . 1.000 +INF .
---- VAR PY . 1.000 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 1.000 +INF .
---- VAR PW . 1.000 +INF .
---- VAR CONS . 200.000 +INF .
A Activity level for sector A (80:20 for X:Y)
B Activity level for sector B (20:80 for X:Y)
W Activity level for sector W (Hicksian welfare index)
PX Price index for commodity X
PY Price index for commodity Y
PL Price index for primary factor L
PK Price index for primary factor K
PW Price index for welfare (expenditure function)
CONS Income level for consumer CONS
Counterfactual model: 10% tax on A sector inputs
S O L V E S U M M A R Y
MODEL M1_3S
LOWER LEVEL UPPER MARGINAL
---- VAR A . 0.778 +INF .
---- VAR B . 1.220 +INF .
---- VAR W . 0.995 +INF .
---- VAR PX . 1.064 +INF .
---- VAR PY . 0.936 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 0.912 +INF .
---- VAR PW . 0.998 +INF .
---- VAR CONS . 198.554 +INF .
Counterfactual model: 100% tax on A sector inputs
S O L V E S U M M A R Y
MODEL M1_3S
LOWER LEVEL UPPER MARGINAL
---- VAR A . . +INF 41.163
---- VAR B . 1.960 +INF .
---- VAR W . 0.896 +INF .
---- VAR PX . 1.227 +INF .
---- VAR PY . 0.705 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 0.667 +INF .
---- VAR PW . 0.930 +INF .
---- VAR CONS . 166.667 +INF .
Algebraic model
S O L V E S U M M A R Y
MODEL ALGEBRAIC
LOWER LEVEL UPPER MARGINAL
---- VAR A . 1.000 +INF .
---- VAR B . 1.000 +INF .
---- VAR W . 1.000 +INF .
---- VAR PX . 1.000 +INF .
---- VAR PY . 1.000 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 1.000 +INF .
---- VAR PW . 1.000 +INF .
---- VAR CONS . 200.000 +INF .
Algebraic model - Counterfactual: 10% tax on sector A inputs
S O L V E S U M M A R Y
MODEL ALGEBRAIC
LOWER LEVEL UPPER MARGINAL
---- VAR A . 0.778 +INF .
---- VAR B . 1.220 +INF .
---- VAR W . 0.995 +INF .
---- VAR PX . 1.064 +INF .
---- VAR PY . 0.936 +INF .
---- VAR PL 1.000 1.000 1.000 8.527E-14
---- VAR PK . 0.912 +INF .
---- VAR PW . 0.998 +INF .
---- VAR CONS . 198.554 +INF .
Algebraic model - Counterfactual: 100% tax on sector A inputs
S O L V E S U M M A R Y
MODEL ALGEBRAIC
LOWER LEVEL UPPER MARGINAL
---- VAR A . . +INF 41.163
---- VAR B . 1.960 +INF .
---- VAR W . 0.896 +INF .
---- VAR PX . 1.227 +INF .
---- VAR PY . 0.705 +INF .
---- VAR PL 1.000 1.000 1.000 4.363E-11
---- VAR PK . 0.667 +INF .
---- VAR PW . 0.930 +INF .
---- VAR CONS . 166.667 +INF .
EXERCISE. Infinite elasticity of transformation in sector A
S O L V E S U M M A R Y
MODEL A1_A2
LOWER LEVEL UPPER MARGINAL
---- VAR B . 1.000 +INF .
---- VAR W . 1.000 +INF .
---- VAR PX . 1.000 +INF .
---- VAR PY . 1.000 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 1.000 +INF .
---- VAR PW . 1.000 +INF .
---- VAR CONS . 200.000 +INF .
---- VAR A1 . 1.000 +INF .
---- VAR A2 . 1.000 +INF .
Counterfactual model: 10% tax on sectors A (A1 and A2) inputs
S O L V E S U M M A R Y
MODEL A1_A2
LOWER LEVEL UPPER MARGINAL
---- VAR B . 1.337 +INF .
---- VAR W . 0.996 +INF .
---- VAR PX . 1.011 +INF .
---- VAR PY . 0.928 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 0.868 +INF .
---- VAR PW . 0.968 +INF .
---- VAR CONS . 192.890 +INF .
---- VAR A1 . 0.823 +INF .
---- VAR A2 . . +INF 1.662
Counterfactual model: 100% tax on sectors A (A1 and A2) inputs
S O L V E S U M M A R Y
MODEL A1_A2
LOWER LEVEL UPPER MARGINAL
---- VAR B . 1.960 +INF .
---- VAR W . 0.896 +INF .
---- VAR PX . 1.227 +INF .
---- VAR PY . 0.705 +INF .
---- VAR PL 1.000 1.000 1.000 EPS
---- VAR PK . 0.667 +INF .
---- VAR PW . 0.930 +INF .
---- VAR CONS . 166.667 +INF .
---- VAR A1 . . +INF 27.312
---- VAR A2 . . +INF 17.271