$TITLE: 10 SEKTORENMODELL / AUSSTIEG AUS DER KERNENERGIE /

*       BESTEUERUNG DES ATOMSTROMS INKL. IMPORT VON ATOMSTROM
*
************************************************************************
*       DEFINITION DER GUETER/HAUSHALTE UND SEKTOREN

SETS
        S Sectors (and goods)   /G_1*G_10/
        IN_AGG(S)               /G_1,G_6*G_10/
        IN_AGGN(S)              /G_5/
        IN_AGGL(S)              /G_2*G_4/
        H consumers             /HH1, HH2/;

ALIAS (G,S);

****************************************************************************
*       DEFINITION DER EINKOMMEN, DER IOT, DER NACHFRAGE, DER STEURSAETZE

TABLE E(*,H) commodity endowments

                        HH1             HH2
KAPITAL                 28065           56129
IMPORT                  28225           56450
ARBEIT                  50151           100303

TABLE D(G,H) reference demands
                        HH1             HH2
G_1                     8688            17376
G_2                     714             1427
G_3                     569             1138
G_4                     41              82
G_5                     2017            4032
G_6                     35712           71424
G_7                     9101            18202
G_8                     28389           56778
G_9                     5512            11023
G_10                    15699           31397;

TABLE INPUT(*,S) Value added production

        G_1     G_2     G_3     G_4     G_5     G_6     G_7     G_8     G_9     G_10
G_1     15615   3       3       0       1       970     11      1317    3418    624
G_2     166     268     214     15      72      657     41      434     243     108
G_3     133     214     171     12      58      524     33      346     194     86
G_4     10      15      12      1       4       38      2       25      14      6
G_5     335     46      37      3       2475    1197    337     1977    149     345
G_6     3832    551     440     32      28      69449   9934    12339   2467    8221
G_7     364     106     84      6       3       323     455     3390    51      855
G_8     5278    460     367     26      110     20209   4837    31739   3522    4751
G_9     327     19      15      1       1       1365    78      2770    127     983
G_10    155     23      18      1       1       690     81      1831    103     653
IMPORT  7631    394     314     23      9706    63090   25      2763    131     598
KAPITAL 9665    1653    1319    95      265     14757   3609    44892   5028    2911
ARBEIT  4515    607     484     35      228     41160   13497   52643   6774    30511  ;


PARAMETER       OUTPUT(S)       BASE YEAR OUTPUT;
OUTPUT(S) = SUM(G,INPUT(G,S)) + INPUT("IMPORT",S) + INPUT("KAPITAL",S) +INPUT("ARBEIT",S);

******************************************************************************
* Definition der Elastizitaetsparameter

PARAMETER ESUB(H) elasticities in demand;                       ESUB(H) = 1;
PARAMETER ESUBM(S) elasticities in domestic production;         ESUBM(S) = 0;
PARAMETER ESUBV(S) elasticities in VA_EN production;            ESUBV(S) = 0.5;
PARAMETER ESUBK(S) elasticities in VA production;               ESUBK(S) = 0.7;
PARAMETER ESUBG(S) elasticities in AGGN production;             ESUBG(S) = 0.6;
PARAMETER ESUBL(S) elasticities in AGGL production;             ESUBL(S) = 1;
PARAMETER ESUBA(S) elasticities in AGG production;              ESUBA(S) = 0;
PARAMETER ESUBY(S) elasticities in final output production;     ESUBY(S) = 1;

*****************************************************************************
*       Definition der Oekonomie in MPS

$ONTEXT

$MODEL:ATOM2NS

$SECTORS:
        Y(S)    !       PRODUCTION FUNCTIONS

$COMMODITIES:
        P(G)    !       MARKET PRICES
        PK      !       KAPITAL
        PA      !       ARBEIT
        PFX     !       FOREIGN EXCHANGE

$CONSUMERS:
        HH(H)   !       HOUSEHOLDS


$PROD:Y(S)      S:ESUBY(S)
+                      DOM:ESUBM(S)
+                 AGG(DOM):ESUBA(S)
+                VAEN(DOM):ESUBV(S)
+                 VA(VAEN):ESUBK(S)
+               AGGN(VAEN):ESUBG(S)
+               AGGL(AGGN):ESUBL(S)
        O:P(S)  Q:OUTPUT(S)
        I:PFX   Q:INPUT("IMPORT",S)
        I:P(G)  Q:INPUT(G,S)            AGG:$IN_AGG(G)  AGGN:$IN_AGGN(G)  AGGL:$IN_AGGL(G)
        I:PK    Q:INPUT("KAPITAL",S)    VA:
        I:PA    Q:INPUT("ARBEIT",S)     VA:

$DEMAND:HH(H)   s:ESUB(H)
        D:P(G)  Q:D(G,H)
        E:PFX   Q:E("IMPORT", H)
        E:PK    Q:E("KAPITAL",H)
        E:PA    Q:E("ARBEIT", H)

$OFFTEXT
$SYSINCLUDE mpsgeset ATOM2NS
******************************************************************************
* BENCHMARKBERECHNUNG

ATOM2NS.ITERLIM = 0;

$INCLUDE ATOM2NS.GEN
SOLVE ATOM2NS USING MCP;
ATOM2NS.ITERLIM = 2000;

SET T /1997*2005/;

PARAMETER       THETA   PRICE INDEX WEIGHTS;

THETA(G) = SUM(H, D(G,H)) / SUM((S,H), D(S,H));

PARAMETER       REPORT  TIME PATH OF KEY VARIABLES;

LOOP(T,

*       Assume a 2% growth rate in labor:

        E("ARBEIT",H) = 1.02*E("ARBEIT",H);

$INCLUDE ATOM2NS.GEN
        SOLVE ATOM2NS USING MCP;


        REPORT(S,T) = 100 * (Y.L(S)-1);
        REPORT("WAGE",T)   = 100 * (PA.L/SUM(G, THETA(G)*P.L(G)) - 1);
        REPORT("RETURN",T) = 100 * (PK.L/SUM(G, THETA(G)*P.L(G)) - 1);
);

OPTION REPORT:1;
DISPLAY REPORT;